Simulación de circuitos

Archivo de Entrada SPICE (tr808_clave.cir)

.title Roland TR-808 Clave
.include TL072.mod

v0 opampout out 0 

r1 inv out 20000k
r2 3   0   0.28k
c1 inv 3   0.0047u
c2 3   out 0.0047u

x1 ninv inv cc ee opampout TL072

vcc cc 0  15
vee ee 0 -15

v1 ninv 0 PULSE(0 10m 1u 0 0 100u 0.25) 

.control
  tran 1us 300ms
  wrdata outputfile v(out)
.endc

.end

TL072.mod

* TL072 OPERATIONAL AMPLIFIER "MACROMODEL" SUBCIRCUIT
* CREATED USING PARTS RELEASE 4.01 ON 06/16/89 AT 13:08
* (REV N/A)      SUPPLY VOLTAGE: +/-15V
* CONNECTIONS:   NON-INVERTING INPUT
*                | INVERTING INPUT
*                | | POSITIVE POWER SUPPLY
*                | | | NEGATIVE POWER SUPPLY
*                | | | | OUTPUT
*                | | | | |
.SUBCKT TL072    1 2 3 4 5
*
  C1   11 12 3.498E-12
  C2    6  7 15.00E-12
  DC    5 53 DX
  DE   54  5 DX
  DLP  90 91 DX
  DLN  92 90 DX
  DP    4  3 DX
  EGND 99  0 POLY(2) (3,0) (4,0) 0 .5 .5
  FB    7 99 POLY(5) VB VC VE VLP VLN 0 4.715E6 -5E6 5E6 5E6 -5E6
  GA    6  0 11 12 282.8E-6
  GCM   0  6 10 99 8.942E-9
  ISS   3 10 DC 195.0E-6
  HLIM 90  0 VLIM 1K
  J1   11  2 10 JX
  J2   12  1 10 JX
  R2    6  9 100.0E3
  RD1   4 11 3.536E3
  RD2   4 12 3.536E3
  RO1   8  5 150
  RO2   7 99 150
  RP    3  4 2.143E3
  RSS  10 99 1.026E6
  VB    9  0 DC 0
  VC    3 53 DC 2.200
  VE   54  4 DC 2.200
  VLIM  7  8 DC 0
  VLP  91  0 DC 25
  VLN   0 92 DC 25
.MODEL DX D(IS=800.0E-18)
.MODEL JX PJF(IS=15.00E-12 BETA=270.1E-6 VTO=-1)
.ENDS

Para Ejecutar la Simulación

• instalar ngspice
• crea un directorio para los archivos de simulación
• crea TL072.mod en ese directorio
• crea tr808_clave.cir en ese directorio
• ejecutar la simulación

ngspice -b tr808_clave.cir

Para ver el resultado de la simulación

Usando GNU Plotutils:

graph -T ps -f 0.04 outputfile > outputfile.ps
ps2pdf outputfile.ps
open outputfile.pdf

El resultado:

•