Mesa musical

Revisión del 19:31 18 nov 2026 de Antonio (discusión | contribs.) (→Código)
(difs.) ← Revisión anterior | Revisión actual (difs.) | Revisión siguiente → (difs.)

Fotos

Código

#include <float.h>

#include <Adafruit_Sensor.h>
#include <Adafruit_ADXL345_U.h>

const int data_points = 5;
const int speaker_pin = 3;

const float base_duration_ms = 40;
const float base_freq = 100.0;
const float dynamic_pitch_factor = 5.0;
const float dynamic_duration_factor = 10.0;
const float note_interval = 1.059463;
const float detection_threshold = 0.4;
const float sensitivity_factor = 20.0;
const float degree_offset = 3.0;
const float baseline_iir_filter_coef = 0.6;
const range_t desired_range = ADXL345_RANGE_4_G;
const dataRate_t desired_rate = ADXL345_DATARATE_3200_HZ;

#define NUM_NOTES 33

int notes[NUM_NOTES] = {0, 2, 3, 5, 7, 8, 10};

Adafruit_ADXL345_Unified accel = Adafruit_ADXL345_Unified();

void setup(void) {
  Serial.begin(115200);
  while (!accel.begin()) {
    Serial.println("accel.begin() failed. We will retry.");
    delay(100);
  }

  while (accel.getRange() != desired_range) {
    Serial.println("setting range");
    accel.setRange(desired_range);
    delay(100);
  }

  while (accel.getDataRate() != desired_rate) {
    Serial.println("setting rate");
    accel.setDataRate(desired_rate);
    delay(100);
  }

  pinMode(speaker_pin, OUTPUT);

  for (int i = 7; i < NUM_NOTES; i++) {
    notes[i] = notes[i - 7] + 12;
  }
  Serial.println("done with setup");
}

float old_max = 50;

void loop(void) {
  float max = FLT_MAX * -1;
  sensors_event_t event;
  for (int i = 0; i < data_points; i++) {
    accel.getEvent(&event);
    max = max(event.acceleration.x, max);
  }
  
  max = sensitivity_factor * sqrt(sqrt(max));

  const bool detected = (max - old_max) > detection_threshold;

  if (detected) {
    int degree = dynamic_pitch_factor * (max - old_max) - degree_offset;

    const int first_index = 0;
    const int last_index = NUM_NOTES - 1;
    degree = max(degree, first_index);
    degree = min(degree, last_index);
    
    const float freq = base_freq * pow(note_interval, notes[degree]);
    noTone(speaker_pin);
    tone(speaker_pin, freq, base_duration_ms + dynamic_duration_factor * degree);

    delay(degree);
    old_max = max;
  }
  
  old_max = baseline_iir_filter_coef * old_max + (1 - baseline_iir_filter_coef) * max;
}