#include <float.h>

#include <Adafruit_Sensor.h>
#include <Adafruit_ADXL345_U.h>

const int data_points = 10;
const int speaker_pin = 3;

const float dynamic_pitch_factor = 5;
const float dynamic_duration_factor = 10;
const int base_duration_ms = 40;
const float base_freq = 100;
const float note_interval = 1.05946;
const float detection_threshold = 0.5;

#define NUM_NOTES 32

int notes[NUM_NOTES] = {0, 2, 3, 5, 7, 8, 10};

Adafruit_ADXL345_Unified accel = Adafruit_ADXL345_Unified();

void setup(void) {
  Serial.begin(115200);
  while (!accel.begin()) {
    delay(100);
  }

  accel.setRange(ADXL345_RANGE_2_G);
  accel.setDataRate(ADXL345_DATARATE_3200_HZ);
  pinMode(speaker_pin, OUTPUT);

  for (int i = 7; i < NUM_NOTES; i++) {
    notes[i] = notes[i - 7] + 12;
  }
}

float old_max = 50;

void loop(void) {
  float max = FLT_MAX * -1;
  sensors_event_t event;
  for (int i = 0; i < data_points; i++) {
    accel.getEvent(&event);
    max = max(event.acceleration.x, max);

    if (false) {
    Serial.print(event.acceleration.x);
    Serial.print(" ");
    Serial.print(event.acceleration.y);
    Serial.print(" ");
    Serial.println(event.acceleration.z);
    }    
  }

  max = 20 * sqrt(sqrt(max));

  const bool detected = (max - old_max) > detection_threshold;

  if (detected) {
    int degree = dynamic_pitch_factor * (max - old_max)- 1.5;
    const int first_index = 1;
    const int last_index = sizeof(notes) / sizeof(*notes) - 1;
    degree = max(degree, first_index);
    degree = min(degree, last_index);
    const float freq = base_freq * pow(note_interval, notes[degree]);
    tone(speaker_pin, freq, base_duration_ms + dynamic_duration_factor * degree);
    const String s = String(max) + " " + String(old_max) + " " + degree + " " + notes[degree] + "\n"; 
    Serial.print(s);

    delay(degree);
    old_max = max;
  }

  old_max = 0.6 * old_max + 0.4 * max;
}